Activer les Logs détaillés du Client SCCM 2007

Lorsque une incident se produit sur nos chers Postes de Travail intégrés à System Center Configuration Manager, notre premier réflexe est de regarder les Logs.

Ces logs situés sous C:\Windows\System32\CCM\Logs (32Bits) ou C:\Windows\SysWOW64\CCM\Logs (64Bits) nous permettent entres autres de connaitre le détail des incident ayant eu lieu lors de déploiements sur la machine.

Cependant, ces logs ne sont parfois pas suffisamment « Verbeux » et ne nous permettent donc pas d’avoir suffisamment de détails.

Après m’être inspiré de divers scripts et autres éléments de configuration j’ai confectionné ce petit script qui vous permettra d’activer les logs détaillés sur vos clients SCCM.

Prenez toute fois garde à la taille des logs, en effet, celle-ci est plafonnée dans le script mais la quantité de logs générés ne vous permettra pas de stocker X jours de logging … (n’oubliez ensuite pas de remettre la valeur de logging originelle modifiée par le script)

Retrouvez ci-dessous le code source du script, ou téléchargez celui-ci ici : ConfSCCMLogging

 
'	Script Name : ConfSCCMLogging.vbs 
' 	Author : Pierre SALVY
' 	Description : This script enable Verbose logging on SCCM Clients.
'	Syntax :
'       Conection to a remote Computer : cscript.exe script.vbs MyComputerName 
' 		Connection to the local computer : cscript.exe script.vbs 

WScript.Echo( "------------------------------------" )
'   Determine the remote machine name / Local machine
if (WScript.Arguments.Count > 0) then
    sMachine = WScript.Arguments(0)
    WScript.Echo( "Connecting to machine " & sMachine)
else
    sMachine = "."
    WScript.Echo( "Connecting to local machine")
end if
WScript.Echo( "------------------------------------" )
'   Connect to the machine's WMI CCM namespace
on error resume next
set Services = GetObject("winmgmts://" & sMachine & "/root/ccm")
if (Err.number <> 0) then
    WScript.Echo( "Failed to connect to WMI on " & sMachine & ": " & Err.Description & " (" & Err.number & ")")
    WScript.Quit -1
end if
WScript.Echo( "Connection to WMI : OK" )

Set oSMS = Services.Get("SMS_Client")
Set LogParams = oSMS.Methods_("SetGlobalLoggingConfiguration").InParameters.SpawnInstance_

' LogLevel : VERBOSE = 0 / INFO = 1 / WARNING = 2 / ERROR = 3 
LogParams.LogLevel      = 0
LogParams.LogMaxSize    = 500000
LogParams.LogMaxHistory = 1
LogParams.DebugLogging = true

Err.Clear
on error resume next
Set oOutParams = Services.ExecMethod( "SMS_Client", "SetGlobalLoggingConfiguration", LogParams)
'See SmsClientMethodProvider.log displays client logging state

if (Err.number = 0) Then
    WScript.Echo( "Create method executed successfully.")
	WScript.Echo( "------------------------------------" )
    WScript.Echo( "LogLevel   = " & LogParams.LogLevel  )  
    WScript.Echo( "LogMaxSise = " & LogParams.LogMaxSize   )
    WScript.Echo( "LogMaxHistory = " & LogParams.LogMaxHistory )
   If (vartype(LogParams.DebugLogging) <> vbnull) Then
      WScript.Echo( "DebugLogging = " & LogParams.DebugLogging )
   End If
End If
WScript.Echo( "------------------------------------" )
If oOutParams.ReturnValue = 0 Then
    WScript.Echo( "Create method FAILED.")
End If
Please follow and like us:

No Responses

Laisser un commentaire

Votre adresse de messagerie ne sera pas publiée. Les champs obligatoires sont indiqués avec *

Social media & sharing icons powered by UltimatelySocial