Désactiver les mises à jour automatiques d’ Adobe Flash Player (AutoUpdates)

Dans le cadre de la gestion des versions déployées sur un parc de postes de travail, il est parfois nécessaire, et pénible de gérer et de fixer les versions d’Adobe Flash Player.

En effet, la configuration (entre autres) des mises a jours automatiques de Flash Player passe UNIQUEMENT par le ficher mms.cfg présent sous « C:\WINDOWS\System32\Macromed\Flash\ » ou « C:\Windows\SysWOW64\ » (Win7x64).

Impossible donc de faire une GPO ajoutant/modifiant une clé Registre, ou impossible d’utiliser un ADM/ADMX puisque Adobe n’en fournit pas pour Flash.

Pour désactiver les mises à jour automatiques et redevenir maître des versions déployées, rien de mieux qu’un script (VBS) déployé sur vos postes ! pour cela, un petit peu de lecture ci dessous devrait faire l’affaire !

 
'----------------------------------------------------------
' Author : P.Salvy
' Disable Flash Player Auto update on Windows XP and 7 x64
'----------------------------------------------------------

On Error Resume Next
'-- Var Init.
Set objFSO = CreateObject("Scripting.FileSystemObject")
FolderPathXP7x86 = "C:\WINDOWS\System32\Macromed\Flash\"
FolderPath7x64 = "C:\Windows\SysWOW64\Macromed\Flash\"
'-- End Var Init.

'-- Start
If  objFSO.FolderExists(FolderPathXP7x86) Then
	createCfgFile (FolderPathXP7x86)
End If

If  objFSO.FolderExists(FolderPath7x64) Then
	createCfgFile (FolderPath7x64)
End If

'-- End

'------------------------ Functions ------------------------
Function createCfgFile (FolderPath)
	' si le fichier de config n'existe pas, le créer et ajouter la config
	if not objFSO.fileExists (FolderPath&"mms.cfg") then
		Set objFile = objFSO.CreateTextFile(FolderPath&"mms.cfg")
		objFile.WriteLine("AutoUpdateDisable=1")
		objFile.Close
	Else 
		' si le fichier de config existe
		Set objFile = objFSO.OpenTextFile(FolderPath&"mms.cfg", 1)
		Configured = false
		'vérifier la présence de la ligne avec la bonne valeur.
		Do Until objFile.AtEndOfStream
			CurrentRead = objFile.ReadLine
			if InStr(1, CurrentRead, "AutoUpdateDisable=1") then
				Configured = True
			End If	
		Loop
		objFile.Close
		Set objFile = objFSO.OpenTextFile(FolderPath&"mms.cfg", 8)
		'si valeur pas OK ou non existante: l'ajouter a la fin du fichier
		If Configured = false then
			objFile.WriteLine("")
			objFile.WriteLine("AutoUpdateDisable=1")
			objFile.Close
		End If
	End If
End Function

Please follow and like us:

Comments

  1. By Patrice

  2. By Bertrand57

  3. By To78

Laisser un commentaire

Votre adresse de messagerie ne sera pas publiée. Les champs obligatoires sont indiqués avec *

Social media & sharing icons powered by UltimatelySocial